Ultra-SiMPLE *
Int x, y, z
Int num, pdl, wall, other
xoff=(xpixels()-640)/2
yoff=(ypixels()-480)/2
randomize; hide mouse
cls; border @
title="      BLOCKOUT\n       - by -\nSiMPLE CodeWorks, Inc"
tabxy (31+xoff/8, 11+yoff/15)
framed text (title, 0, 7, 7)
bugle @
Do
   tabxy (30+xoff/8, 19+yoff/15)
   framed text ("Press a mouse button...", 14, 3, 7)
   Do
      read mouse (x, y, z)
      If (z) Break
      read quitkey (27)
      wait (0)
   Loop
   cls; border @
   Do k=1,15
      tile (k,  5, 13) @
      tile (k,  8,  9) @
      tile (k, 11, 10) @
      tile (k, 14, 14) @
      tile (k, 17, 12) @
   Loop
   tiles=75
   xball=320.0; yball=270.0; len=60
   Do
      vector=random(20001)-10000
      If iabs(vector)>3500 Break
   Loop
   Do
      read mouse (x, y, z)
      paddle (x, 30, len) @
      paddle (x, 450, len) @
      move ball (xball, yball, vector) @
      zap tile (num, pdl, wall, other) @
      If pdl Or wall Or num
         If (num) pop @
         If wall=1 Or wall=3 Or wall=9 Break
         If wall=4 Or wall=6 Or wall=12 Break
         tiles=tiles-num; If !tiles Break
         If pdl
            english (vector) @
            len=len-1
         Endif
      Endif
      If (getmode()) wait (0)
      Else wait quit key (27, 2)
   Loop
   tabxy (37+xoff/8, 11+yoff/15)
   If tiles
      framed text ("You lose!", 14, 4, 7)
      booboo @
   Endif
   Else
      explode(int(xball), int(yball)) @toys
      border @
      framed text ("You Win!", 11, 1, 7)
      bugle @
   Endelse
Loop
Append L: kit